File:Elliptic orbit.svg é uma versão vetorial deste ficheiro. Ela deve ser usada em vez desta imagem em formato raster, se não for de qualidade inferior. File:Elliptic orbit.gif → File:Elliptic orbit.svg Para mais informações, consulte Ajuda:SVG. Em outras línguas Alemannisch ∙ Bahasa Indonesia ∙ Bahasa Melayu ∙ British English ∙ català ∙ čeština ∙ dansk ∙ Deutsch ∙ eesti ∙ English ∙ español ∙ Esperanto ∙ euskara ∙ français ∙ Frysk ∙ galego ∙ hrvatski ∙ Ido ∙ italiano ∙ lietuvių ∙ magyar ∙ Nederlands ∙ norsk bokmål ∙ norsk nynorsk ∙ occitan ∙ Plattdüütsch ∙ polski ∙ português ∙ português do Brasil ∙ română ∙ Scots ∙ sicilianu ∙ slovenčina ∙ slovenščina ∙ suomi ∙ svenska ∙ Tiếng Việt ∙ Türkçe ∙ vèneto ∙ Ελληνικά ∙ беларуская (тарашкевіца) ∙ български ∙ македонски ∙ нохчийн ∙ русский ∙ српски / srpski ∙ татарча/tatarça ∙ українська ∙ ქართული ∙ հայերեն ∙ বাংলা ∙ தமிழ் ∙ മലയാളം ∙ ไทย ∙ 한국어 ∙ 日本語 ∙ 简体中文 ∙ 繁體中文 ∙ עברית ∙ العربية ∙ فارسی ∙ +/−

 

Descrição do ficheiro

Licenciamento

Eu, titular dos direitos de autor desta obra, publico-a com as seguintes licenças:

É concedida permissão para copiar, distribuir e/ou modificar este documento nos termos da Licença de Documentação Livre GNU, versão 1.2 ou qualquer versão posterior publicada pela Free Software Foundation; sem Secções Invariantes, sem textos de Capa e sem textos de Contra-Capa. É incluída uma cópia da licença na secção intitulada GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

	A utilização deste ficheiro é regulada nos termos da licença Creative Commons - Atribuição-CompartilhaIgual 3.0 Não Adaptada.
	Pode: partilhar – copiar, distribuir e transmitir a obra recombinar – criar obras derivadas De acordo com as seguintes condições: atribuição – Tem de fazer a devida atribuição da autoria, fornecer uma hiperligação para a licença e indicar se foram feitas alterações. Pode fazê-lo de qualquer forma razoável, mas não de forma a sugerir que o licenciador o apoia ou subscreve o seu uso da obra. partilha nos termos da mesma licença – Se remisturar, transformar ou ampliar o conteúdo, tem de distribuir as suas contribuições com a mesma licença ou uma licença compatível com a original.
	Esta marca de licenciamento foi adicionada a este ficheiro durante a atualização da licença GFDL.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue

A utilização deste ficheiro é regulada nos termos da licença Creative Commons - Atribuição-CompartilhaIgual 2.5 Espanha.

Pode:

• partilhar – copiar, distribuir e transmitir a obra
• recombinar – criar obras derivadas

De acordo com as seguintes condições:

• atribuição – Tem de fazer a devida atribuição da autoria, fornecer uma hiperligação para a licença e indicar se foram feitas alterações. Pode fazê-lo de qualquer forma razoável, mas não de forma a sugerir que o licenciador o apoia ou subscreve o seu uso da obra.
• partilha nos termos da mesma licença – Se remisturar, transformar ou ampliar o conteúdo, tem de distribuir as suas contribuições com a mesma licença ou uma licença compatível com a original.

https://creativecommons.org/licenses/by-sa/2.5/es/deed.enCC BY-SA 2.5 esCreative Commons Attribution-Share Alike 2.5 estruetrue

Pode escolher a licença que quiser.

POV-Ray Scene description

POV-ray image description:

   /*
   --------------------------
   Elliptical Orbit Animation
   --------------------------
   Created 7 Mar. 2006
   */    
   
   #include "colors.inc"
   
   //Orbit Definition
   #declare OrbitA=42.164;
   #declare OrbitE=0.7;
   
   //Scene constants
   #declare EarthRadius=6.356;
   #declare SatRadius=1.2;
   #declare OrbitWidth=0.3;
   #declare LineWidth=0.5/3;
   #declare Crosslength=1.5;
   #declare Textscale=9;
   #declare TextColor=rgb<0,0,0>;
   #declare PI=3.14159265359;
   
   //Variables
   #declare M=clock*360;
   #declare prevAnomaly=0;
   #declare Anomaly=0;
   #declare PI=3.14159265359;
   
   //Anomaly Determination - Solves the equation M=E-e*sin(E) by the iterative method
   #declare Index=0;
   #while (Index<20)
       #declare Anomaly=M*(PI/180)-OrbitE*sin(prevAnomaly);
       #declare prevAnomaly=Anomaly;
       #declare Index=Index+1;
   #end
   
   global_settings{
       ambient_light 1
   }
   
   light_source { <-50, 0, -70> color White }
   
   camera {
       orthographic
       location <OrbitA*OrbitE, 0, -10>
       look_at  <OrbitA*OrbitE, 0,  0>
       up <0,100,0>
       right <100,0,0>
   }
   
   plane { <0, 0, 1>, 8
       pigment {White}
       finish{ambient 1 brilliance 0}
   }
   
   //Earth
   sphere {
       <0, 0, 0>, EarthRadius
       pigment { Blue }
       finish{ ambient 0.3 brilliance 1.2 diffuse 0.8}
   }
   
   //Orbit
   torus{
       OrbitA,OrbitWidth
       rotate x*90
       pigment{ rgb<0.8,0,0> }
       finish{ ambient 1 brilliance 0 diffuse 0} 
       scale sqrt(1-OrbitE*OrbitE)*y
       translate x*OrbitA*OrbitE
       no_shadow
   }
   
   //Sat
   sphere {
       <0, 0, -10>, SatRadius
       pigment { SeaGreen }
       finish{ ambient 1 brilliance 0 diffuse 0}
       no_shadow
       translate <OrbitA*(cos(Anomaly)+OrbitE),OrbitA*sqrt(1-OrbitE*OrbitE)*sin(Anomaly),0>
   }
   
   //Lines
   #declare crossBars=
   object{
       union{
           box{
               <-LineWidth,-Crosslength,-LineWidth-7>, <LineWidth,Crosslength,LineWidth-7> 
           }
           box{
               <-Crosslength,-LineWidth,-LineWidth-7>, <Crosslength,LineWidth,LineWidth-7>
           }
           rotate z*45
           pigment{ TextColor }
           finish{ ambient 1 brilliance 0 diffuse 0}
           no_shadow
       }
   }
   
   box{
       <-OrbitA*(1-OrbitE),-LineWidth,-LineWidth-7>, <OrbitA*(1+OrbitE),LineWidth,LineWidth-7> 
       pigment{ TextColor }
       finish{ ambient 1 brilliance 0 diffuse 0}
       no_shadow
   }
   
   
   object{
       crossBars
   }
   
   object{
       crossBars
       translate -x*OrbitA*(1-OrbitE)
   }
   
   object{
       crossBars
       translate x*OrbitA*(1+OrbitE)
   }
   
   //Text
   union{
       text {
           ttf "timesi.ttf" "r" 1, 0
       }
       text {
           ttf "timesi.ttf" "p" 1, 0
           scale 0.5
           translate 0.2*x
       }
       pigment{ TextColor }
       finish{ ambient 1 brilliance 0 diffuse 0}
       scale Textscale
       translate <-(EarthRadius+0.3*(OrbitA*(1-OrbitE)-EarthRadius))-Textscale/4,Textscale/4,-7>
       no_shadow
   }
   
   union{
       text {
           ttf "timesi.ttf" "r" 1, 0
       }
       text {
           ttf "timesi.ttf" "a" 1, 0
           scale 0.5
           translate 0.2*x
       }
       pigment{ TextColor }
       finish{ ambient 1 brilliance 0 diffuse 0}
       scale Textscale
       translate <0.5*OrbitA*(1+OrbitE)-Textscale/4,Textscale/4,-7>
       no_shadow
   }